home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 007 / pctecap.arc / SUPEREN.ASM < prev    next >
Assembly Source File  |  1986-03-15  |  2KB  |  70 lines
  1.     PAGE 
  2.     PAGE    72,120 
  3. TITLE    SUPEREN   Change name of file, sub-dir or vol ID.
  4.  
  5.  
  6. COMMENT "    SUPEREN   [d:]name1    name2 
  7.     Renames files or subdirectories from name 1 to name2. 
  8.     Name1 & name2 may have extensions and wild characters.
  9.     Action of the program is as described in the DOS manual
  10.     for INT 21, function 17. 
  11. " 
  12. COM    SEGMENT 
  13.     ASSUME CS:COM, DS:COM, ES:COM, SS:COM 
  14.  
  15.     ORG    5CH    ;FCB FORMED FROM NAME1 
  16. FCB1    LABEL    BYTE 
  17. DRIVE1    DB    ? 
  18. NAME1    DB    11 DUP(?) 
  19.  
  20.     ORG    6CH    ;FCB FORMED FROM NAME2 
  21. FCB2    LABEL    BYTE 
  22. DRIVE2    DB    ? 
  23. NAME2    DB    11 DUP(?) 
  24.  
  25.     ORG    100H 
  26. SUPEREN    PROC 
  27.     MOV    DX,OFFSET INVDR$    ;POINT TO ERROR MESSAGE 
  28.     TEST    AL,AL        ;TEST FOR VALID DRIVE1 ID 
  29.     JNZ    ERROR 
  30.     MOV    DX,OFFSET INVPAR$ 
  31.     CMP    NAME1,' '        ;CHECK IF NAME1 IS THERE 
  32.     JE    ERROR 
  33.     CMP    NAME2,' '        ;CHECK FOR NAME 2 
  34.     JE    ERROR 
  35.  
  36.     MOV    SI,OFFSET FCB1        ;POINT TO NAME1 FCB 
  37.     MOV    DI,OFFSET OLDN        ;POINT TO OLD NAME FIELD 
  38.     MOV    CX,12        ;MOVE 12 BYTES 
  39.     REP    MOVSB        ;MOVE NAME1 TO EXTENDED FCB 
  40.     MOV    SI,OFFSET NAME2    ;POINT TO NAME2, NOT DRIVE 
  41.     MOV    DI,OFFSET OLDN+11H    ;POINT TO NEW NAME FIELD 
  42.     MOV    CX,11        ;NAME EX DRIVE = 11 BYTES 
  43.     REP    MOVSB        ;MOVE NAME2 TO EXTENDED FCB 
  44.  
  45.      MOV    DX,OFFSET XFCB        ;POINT DX TO EXTENDED FCB 
  46.     MOV    AH,17H        ;FUNCTION 17 = RENAME 
  47.     INT    21H 
  48.  
  49.     TEST    AL,AL        ;TEST FOR ERRORS 
  50.     JZ    EXIT        ;NO ERRORS IF AL = 0 
  51.     MOV    DX,OFFSET INVNAM$    ;ELSE POINT TO ERROR MSG 
  52. ERROR:    MOV    AH,9        ;DISPLAY ERROR MESSAGE 
  53.     INT    21H 
  54. EXIT:    INT    20H        ;RETURN TO DOS 
  55. SUPEREN    ENDP 
  56.  
  57. INVDR$    DB    0DH,0AH,'Invalid drive id$',0DH,0AH,'$' 
  58. INVPAR$    DB    0DH,0AH,'2 params needed: [d:]oldname, newname'
  59.  
  60.     DB    0DH,0AH,'$' 
  61. INVNAM$    DB    0DH,0AH,'Name not found or already exists' 
  62.     DB    0DH,0AH,'$' 
  63.  
  64. XFCB    DB    0FFH    ;EXTENDED FCB ID BYTE 
  65.     DB    5 DUP(0) 
  66. ATTR    DB    18H    ;ATTR FOR SUB-DIRS & VOL LABELS 
  67. OLDN    DB    37 DUP(0)    ;OLD & NEW NAMES GO HERE 
  68.  
  69. COM    ENDS 
  70.     END    SUPEREN